Добавлены конфиги tmux и zsh

zsh/plugins/colorize/README.md

@@ -0,0 +1,35 @@
+# colorize
+
+With this plugin you can syntax-highlight file contents of over 300 supported languages and other text formats.
+
+Colorize will highlight the content based on the filename extension. If it can't find a syntax-highlighting
+method for a given extension, it will try to find one by looking at the file contents. If no highlight method
+is found it will just cat the file normally, without syntax highlighting.
+
+To use it, add colorize to the plugins array of your zshrc file:
+```
+plugins=(... colorize)
+```
+
+## Styles
+
+Pygments offers multiple styles. By default, the `default` style is used, but you can choose another theme by setting the `ZSH_COLORIZE_STYLE` environment variable:
+
+`ZSH_COLORIZE_STYLE="colorful"`
+
+## Usage
+
+* `ccat  <file> [files]`: colorize the contents of the file (or files, if more than one are provided). 
+  If no arguments are passed it will colorize the standard input or stdin.
+
+* `cless <file> [files]`: colorize the contents of the file (or files, if more than one are provided) and
+  open less. If no arguments are passed it will colorize the standard input or stdin.
+
+Note that `cless` will behave as less when provided more than one file: you have to navigate files with
+the commands `:n` for next and `:p` for previous. The downside is that less options are not supported.
+But you can circumvent this by either using the LESS environment variable, or by running `ccat file1 file2|less --opts`.
+In the latter form, the file contents will be concatenated and presented by less as a single file.
+
+## Requirements
+
+You have to install Pygments first: [pygments.org](http://pygments.org/download/)

zsh/plugins/colorize/colorize.plugin.zsh

@@ -0,0 +1,57 @@
+# easier alias to use the plugin
+alias ccat='colorize_via_pygmentize'
+alias cless='colorize_via_pygmentize_less'
+
+colorize_via_pygmentize() {
+    if ! (( $+commands[pygmentize] )); then
+        echo "package 'Pygments' is not installed!"
+        return 1
+    fi
+
+    # If the environment varianle ZSH_COLORIZE_STYLE
+    # is set, use that theme instead. Otherwise,
+    # use the default.
+    if [ -z $ZSH_COLORIZE_STYLE ]; then
+        ZSH_COLORIZE_STYLE="default"
+    fi
+
+    # pygmentize stdin if no arguments passed
+    if [ $# -eq 0 ]; then
+        pygmentize -O style="$ZSH_COLORIZE_STYLE" -g
+        return $?
+    fi
+
+    # guess lexer from file extension, or
+    # guess it from file contents if unsuccessful
+
+    local FNAME lexer
+    for FNAME in "$@"
+    do
+        lexer=$(pygmentize -N "$FNAME")
+        if [[ $lexer != text ]]; then
+            pygmentize -O style="$ZSH_COLORIZE_STYLE" -l "$lexer" "$FNAME"
+        else
+            pygmentize -O style="$ZSH_COLORIZE_STYLE" -g "$FNAME"
+        fi
+    done
+}
+
+colorize_via_pygmentize_less() (
+    # this function is a subshell so tmp_files can be shared to cleanup function
+    declare -a tmp_files 
+
+    cleanup () {
+        [[ ${#tmp_files} -gt 0 ]] && rm -f "${tmp_files[@]}"
+        exit
+    }
+    trap 'cleanup' EXIT HUP TERM INT
+
+    while (( $# != 0 )); do     #TODO: filter out less opts
+        tmp_file="$(mktemp -t "tmp.colorize.XXXX.$(sed 's/\//./g' <<< "$1")")"
+        tmp_files+=("$tmp_file")
+        colorize_via_pygmentize "$1" > "$tmp_file"
+        shift 1
+    done
+
+    less -f "${tmp_files[@]}"
+)